Remove Label wrappers for target string literals

Removes all the `Label` wrappers added in bazel-contrib#1696 that aren't strictly
necessary.

Removed instances:

```sh
$ git show -p | grep '^- .*Label(' | wc -l
    88
```

Remaining instances:

```sh
$ git ls-files | xargs grep '[^A-Za-z0-9]Label(' | wc -l
    31
```

Inspired by research I did while writing a blog post reflecting upon the
motivations behind bazel-contrib#1696.

Bazel evaluates target string literals in the context of the repository
that appears to contain the assignment of the literal to a `Label`
attribute. `Label` wrappers are only necessary for target string
literals within `BUILD` macros and `BUILD` or `.bzl` files generated by
a repository rule. This ensures that the targets refer to the
originating repository by preventing Bazel from interpreting them within
the context of the repository using them.

Keeping the `Label` wrappers doesn't hurt, but leaving only the ones
that are required helps those instances stand out.

Author: mbland

jmh/jmh.bzl

@@ -39,12 +39,12 @@ scala_generate_benchmark = rule(
         "_generator": attr.label(
             executable = True,
             cfg = "exec",
-            default = Label(
-                "//src/scala/io/bazel/rules_scala/jmh_support:benchmark_generator",
+            default = (
+                "//src/scala/io/bazel/rules_scala/jmh_support:benchmark_generator"
             ),
         ),
         "runtime_jdk": attr.label(
-            default = Label("@rules_java//toolchains:current_java_runtime"),
+            default = "@rules_java//toolchains:current_java_runtime",
             providers = [java_common.JavaRuntimeInfo],
         ),
     },

jmh/toolchain/toolchain.bzl

@@ -39,7 +39,7 @@ jmh_toolchain = rule(
     },
 )
 
-_toolchain_type = Label("//jmh/toolchain:jmh_toolchain_type")
+_toolchain_type = "//jmh/toolchain:jmh_toolchain_type"
 
 def _export_toolchain_deps_impl(ctx):
     return expose_toolchain_deps(ctx, _toolchain_type)
@@ -64,7 +64,7 @@ def setup_jmh_toolchain(name):
     native.toolchain(
         name = name,
         toolchain = ":%s_impl" % name,
-        toolchain_type = _toolchain_type,
+        toolchain_type = Label(_toolchain_type),
         visibility = ["//visibility:public"],
     )
 

scala/plusone.bzl

@@ -10,7 +10,7 @@ PlusOneDeps = provider(
 )
 
 def _collect_plus_one_deps_aspect_impl(target, ctx):
-    toolchain = ctx.toolchains[Label("//scala:toolchain_type")]
+    toolchain = ctx.toolchains["//scala:toolchain_type"]
     if toolchain.dependency_mode != "plus-one":
         return []
 
@@ -26,5 +26,5 @@ def _collect_plus_one_deps_aspect_impl(target, ctx):
 collect_plus_one_deps_aspect = aspect(
     implementation = _collect_plus_one_deps_aspect_impl,
     attr_aspects = ["deps", "exports"],
-    toolchains = [Label("//scala:toolchain_type")],
+    toolchains = ["//scala:toolchain_type"],
 )

scala/private/common_attributes.bzl

@@ -29,7 +29,7 @@ common_attrs_for_plugin_bootstrapping = {
     "resource_strip_prefix": attr.string(),
     "resource_jars": attr.label_list(allow_files = True),
     "java_compile_toolchain": attr.label(
-        default = Label("@rules_java//toolchains:current_java_toolchain"),
+        default = "@rules_java//toolchains:current_java_toolchain",
         providers = [java_common.JavaToolchainInfo],
     ),
     "scalacopts": attr.string_list(),
@@ -56,8 +56,8 @@ common_attrs.update(common_attrs_for_plugin_bootstrapping)
 
 common_attrs.update({
     "_dependency_analyzer_plugin": attr.label(
-        default = Label(
-            "//third_party/dependency_analyzer/src/main:dependency_analyzer",
+        default = (
+            "//third_party/dependency_analyzer/src/main:dependency_analyzer"
         ),
         allow_files = [".jar"],
         mandatory = False,
@@ -73,9 +73,7 @@ common_attrs.update({
     ),
     "unused_dependency_checker_ignored_targets": attr.label_list(default = []),
     "_code_coverage_instrumentation_worker": attr.label(
-        default = Label(
-            "//src/java/io/bazel/rulesscala/coverage/instrumenter",
-        ),
+        default = "//src/java/io/bazel/rulesscala/coverage/instrumenter",
         allow_files = True,
         executable = True,
         cfg = "exec",
@@ -84,35 +82,35 @@ common_attrs.update({
 
 implicit_deps = {
     "_java_runtime": attr.label(
-        default = Label("@rules_java//toolchains:current_java_runtime"),
+        default = "@rules_java//toolchains:current_java_runtime",
     ),
     "_java_host_runtime": attr.label(
-        default = Label("@rules_java//toolchains:current_host_java_runtime"),
+        default = "@rules_java//toolchains:current_host_java_runtime",
     ),
     "_scalac": attr.label(
         executable = True,
         cfg = "exec",
-        default = Label("//src/java/io/bazel/rulesscala/scalac"),
+        default = "//src/java/io/bazel/rulesscala/scalac",
         allow_files = True,
     ),
     "_exe": attr.label(
         executable = True,
         cfg = "exec",
-        default = Label("//src/java/io/bazel/rulesscala/exe:exe"),
+        default = "//src/java/io/bazel/rulesscala/exe:exe",
     ),
 }
 
 launcher_template = {
     "_java_stub_template": attr.label(
-        default = Label("//java_stub_template/file"),
+        default = "//java_stub_template/file",
     ),
 }
 
 # Single dep to allow IDEs to pickup all the implicit dependencies.
 resolve_deps = {
     "_scala_toolchain": attr.label_list(
         default = [
-            Label("//scala/private/toolchain_deps:scala_library_classpath"),
+            "//scala/private/toolchain_deps:scala_library_classpath",
         ],
         allow_files = False,
     ),

scala/private/coverage_replacements_provider.bzl

@@ -67,7 +67,7 @@ def _aspect_impl(target, ctx):
 _aspect = aspect(
     attr_aspects = _dependency_attributes,
     implementation = _aspect_impl,
-    toolchains = [Label("//scala:toolchain_type")],
+    toolchains = ["//scala:toolchain_type"],
 )
 
 coverage_replacements_provider = struct(

scala/private/dependency.bzl

@@ -43,13 +43,13 @@ def get_strict_deps_mode(ctx):
     if not hasattr(ctx.attr, "_dependency_analyzer_plugin"):
         return "off"
 
-    return ctx.toolchains[Label("//scala:toolchain_type")].strict_deps_mode
+    return ctx.toolchains["//scala:toolchain_type"].strict_deps_mode
 
 def get_compiler_deps_mode(ctx):
     if not hasattr(ctx.attr, "_dependency_analyzer_plugin"):
         return "off"
 
-    return ctx.toolchains[Label("//scala:toolchain_type")].compiler_deps_mode
+    return ctx.toolchains["//scala:toolchain_type"].compiler_deps_mode
 
 def _is_strict_deps_on(ctx):
     return get_strict_deps_mode(ctx) != "off"

scala/private/phases/phase_compile.bzl

@@ -91,7 +91,7 @@ def phase_compile_common(ctx, p):
     return _phase_compile_default(ctx, p)
 
 def _phase_compile_default(ctx, p, _args = struct()):
-    toolchain = ctx.toolchains[Label("//scala:toolchain_type")]
+    toolchain = ctx.toolchains["//scala:toolchain_type"]
     buildijar_default_value = toolchain.scala_version.startswith("2.")
 
     return _phase_compile(

scala/private/phases/phase_coverage_runfiles.bzl

@@ -21,7 +21,7 @@ def phase_coverage_runfiles(ctx, p):
             coverage_replacements[jar] if jar in coverage_replacements else jar
             for jar in rjars.to_list()
         ])
-        jacocorunner = ctx.toolchains[Label("//scala:toolchain_type")].jacocorunner
+        jacocorunner = ctx.toolchains["//scala:toolchain_type"].jacocorunner
         coverage_runfiles = jacocorunner.files.to_list() + ctx.files._lcov_merger + coverage_replacements.values()
     return struct(
         coverage_runfiles = coverage_runfiles,

scala/private/phases/phase_dependency.bzl

@@ -35,7 +35,7 @@ def _phase_dependency(
         p,
         unused_deps_always_off,
         strict_deps_always_off):
-    toolchain = ctx.toolchains[Label("//scala:toolchain_type")]
+    toolchain = ctx.toolchains["//scala:toolchain_type"]
 
     target_label = str(ctx.label)
 
@@ -81,7 +81,7 @@ def _get_unused_deps_mode(ctx):
     if ctx.attr.unused_dependency_checker_mode:
         return ctx.attr.unused_dependency_checker_mode
     else:
-        return ctx.toolchains[Label("//scala:toolchain_type")].unused_dependency_checker_mode
+        return ctx.toolchains["//scala:toolchain_type"].unused_dependency_checker_mode
 
 def _is_target_included(target, includes, excludes):
     for exclude in excludes:

scala/private/phases/phase_scalac_provider.bzl

@@ -7,7 +7,7 @@ load("//scala/private/toolchain_deps:toolchain_deps.bzl", "find_deps_info_on")
 load("//scala:providers.bzl", _ScalacProvider = "ScalacProvider")
 
 def phase_scalac_provider(ctx, p):
-    toolchain_type_label = Label("//scala:toolchain_type")
+    toolchain_type_label = "//scala:toolchain_type"
 
     library_classpath = find_deps_info_on(ctx, toolchain_type_label, "scala_library_classpath").deps
     compile_classpath = find_deps_info_on(ctx, toolchain_type_label, "scala_compile_classpath").deps